スポンサーサイト

上記の広告は1ヶ月以上更新のないブログに表示されています。
新しい記事を書く事で広告が消せます。

F#で入門 コンパイラ、インタプリタ編 Whitespace(6)

 今回はヒープへのアクセス関連命令を実装していきます。 
これは、「アドレス(データを書き込む場所)とデータを与えて、そこのアドレスに、値を記憶させる」作用と、「アドレスから、そこに記憶されている値を取り出す」作用です。 
 
まず記憶させる方は命令ttsで表され、スタックの値を二つとりだして、(先に取り出したほうをy、あとから取り出した方をxとします)x番地に値yを記憶させます。 
 
取り出す方は命令tttで表され、スタックの値を一つとりだして、その値の番地にある値が代わりにスタックにプッシュされるようにします。 
 
なお、ヒープはMap<int,int>で表すことにしたのでした。 
 
例 
> Map.ofList [(1001,34);(1002,59)];; 
val it : Map<int,int> = map [(1001, 34); (1002, 59)] 
 
というようなMapで、1001番地に34が10021番地に59が、記録させてあると解釈します。 
 
追加変更場所は4か所です。 
 
(1)Command Type への追加 
type Command = 
    |SPush of int 
    ........... 
    |TTStore 
    |TTRetrieve 
 
(2)ComKindLstへの追加 
 
let ComKindLst = 
     [(new Regex("^ss(?<num_part>(s|t)(s|t)+)n"), 
        (fun (rg:Regex) str -> createFromInt "num_part" rg str (fun num -> SPush(num)))); 
............. 
      ( new Regex("^tts"), 
        (fun (rg:Regex) str -> createFromNothing rg str (fun () -> TTStore))); 
      ( new Regex("^ttt"), 
        (fun (rg:Regex) str -> createFromNothing rg str (fun () -> TTRetrieve))); 
............. 
 
(3)対応する関数の追加 
 
let do_TTStore ((pc,stcLst,heapMap,rIndexLst):WState) = 
    match stcLst with 
    |v1::v2::rem -> (pc+1,rem,Map.add v2 v1 heapMap,rIndexLst) 
    |_    ->failwith(sprintf "index:%d スタックの要素数がたりずにStoreできません。" pc) 
 
let do_TTRetrieve ((pc,stcLst,heapMap,rIndexLst):WState) = 
    match stcLst with 
    |v::rem -> let retreivedVal = Map.tryFind v heapMap 
               if retreivedVal.IsSome then 
                    (pc+1,retreivedVal.Value::rem,heapMap,rIndexLst) 
               else failwith(sprintf "index:%d 指定されたアドレスにデータがないためRetrieveできません。" pc) 
    |_    ->failwith(sprintf "index:%d スタックの要素数がたりずにRetrieveできません。" pc) 
 
(4)processCmdへの追加 
 
let rec processCmd (cmds :Command[]) ((pc,stcLst,heapMap,rIndexLst) as t:WState) = 
    if pc < 0 || pc >= Array.length cmds then failwith (sprintf "index:%d pcが領域外です" pc) 
    printfn "%A" t  //デバック用 
    let cur_cmd = cmds.[pc] 
    printfn "%A" cur_cmd //デバック用 
    match cur_cmd with 
    |SPush(num)  -> do_SPush num t  |> (processCmd cmds) 
    |SDup        -> do_SDup t       |> (processCmd cmds) 
........................ 
    |TTStore     -> do_TTStore t    |> (processCmd cmds) //ここが追加分 
    |TTRetrieve  -> do_TTRetrieve t |> (processCmd cmds) //ここが追加分 
 
(使用例1) 
> processCmd [|SPush(1001);SPush(56);TTStore;SPush(1001);TTRetrieve;FExit|] (0,[],Map.empty,[]);; 
(0, [], map [], []) 
SPush 1001 
(1, [1001], map [], []) 
SPush 56 
(2, [56; 1001], map [], []) 
TTStore 
(3, [], map [(1001, 56)], []) 
SPush 1001 
(4, [1001], map [(1001, 56)], []) 
TTRetrieve 
(5, [56], map [(1001, 56)], []) 
FExit 
val it : unit = () 
 
(使用例2) 
> processCmd [|SPush(1001);SPush(56);TTStore;SPush(1002);TTRetrieve;FExit|] (0,[],Map.empty,[]);; 
(0, [], map [], []) 
SPush 1001 
(1, [1001], map [], []) 
SPush 56 
(2, [56; 1001], map [], []) 
TTStore 
(3, [], map [(1001, 56)], []) 
SPush 1002 
(4, [1002], map [(1001, 56)], []) 
TTRetrieve 
System.Exception: index:4 指定されたアドレスにデータがないためRetrieveできません。 
........................ 
エラーのため停止しました 
 
ここまでの全コードは次の通りです。 
 open System.Text.RegularExpressions 
 
////////////////正規表現用の補助関数/////////////// 
 
let myReplace (regStr:string) (repStr:string) (oriSrcStr:string)= 
    (new Regex(regStr)).Replace(oriSrcStr,repStr) 
 
///////////////視覚化関数////////////////////////// 
 
let visualize (src:string) = 
    src 
    |> myReplace "[^\s]" "" 
    |> myReplace " " "s" 
    |> myReplace "\t" "t" 
    |> myReplace "\n" "n" 
 
/////////////s,t,nによる数値表現をintに変換する関数// 
 
let wToNum (str:string) = 
    let strbiNum = 
        str.Substring(1) 
        |> myReplace "s" "0" 
        |> myReplace "t" "1" 
    let absPart10 = System.Convert.ToInt32 (strbiNum,2) 
    printfn "%A" (str.Substring(0)) 
    if str.Substring(0,1) = "s" then absPart10 
    elif str.Substring(0,1) = "t" then (-1)*absPart10 
    else failwith "数値表現エラー" 
 
/////////////プログラムの中核をなすコマンド型/////// 
 
type Command = 
    |SPush of int 
    |SDup 
    |SCopy of int 
    |SSwap 
    |SDiscard 
    |SSlide of int 
    |TSAdd 
    |TSSub 
    |TSMul 
    |TSDiv 
    |TSMod 
    |TTStore 
    |TTRetrieve 
    |FExit 
 
/////////////正規表現で切り出す補助関数群///////// 
 
let createFromInt (partStr:string) (rg:Regex) (str:string) (creInt:int->Command) = 
         let wholeMatch = rg.Match(str) 
         let partMatch = wholeMatch.Groups.[partStr] 
         if partMatch.Value.Length > 0 then 
            Some(creInt(wToNum partMatch.Value),wholeMatch.Length) 
         else 
            None 
 
let createFromNothing (rg:Regex) (str:string) (cre:unit->Command) = 
        let wholeMatch = rg.Match(str) 
        if wholeMatch.Success = true then 
               Some(cre(),wholeMatch.Length) 
        else None 
 
/////////////正規表現での切り出し対応タプルリスト// 
 
let ComKindLst = 
     [(new Regex("^ss(?<num_part>(s|t)(s|t)+)n"), 
        (fun (rg:Regex) str -> createFromInt "num_part" rg str (fun num -> SPush(num)))); 
      ( new Regex("^sns"), 
        (fun (rg:Regex) str -> createFromNothing rg str (fun () -> SDup))); 
      ( new Regex("^sts(?<num_part>(s|t)(s|t)+)n"), 
        (fun (rg:Regex) str -> createFromInt "num_part" rg str (fun num -> SCopy(num)))); 
      ( new Regex("^snt"), 
        (fun (rg:Regex) str -> createFromNothing rg str (fun () -> SSwap))); 
      ( new Regex("^snn"), 
        (fun (rg:Regex) str -> createFromNothing rg str (fun () -> SDiscard))); 
      ( new Regex("^stn(?<num_part>(s|t)(s|t)+)n"), 
        (fun (rg:Regex) str -> createFromInt "num_part" rg str (fun num -> SSlide(num)))); 
      ( new Regex("^tsss"), 
        (fun (rg:Regex) str -> createFromNothing rg str (fun () -> TSAdd))); 
      ( new Regex("^tsst"), 
        (fun (rg:Regex) str -> createFromNothing rg str (fun () -> TSSub))); 
      ( new Regex("^tssn"), 
        (fun (rg:Regex) str -> createFromNothing rg str (fun () -> TSMul))); 
      ( new Regex("^tsts"), 
        (fun (rg:Regex) str -> createFromNothing rg str (fun () -> TSDiv))); 
      ( new Regex("^tstt"), 
        (fun (rg:Regex) str -> createFromNothing rg str (fun () -> TSMod))); 
      ( new Regex("^tts"), 
        (fun (rg:Regex) str -> createFromNothing rg str (fun () -> TTStore))); 
      ( new Regex("^ttt"), 
        (fun (rg:Regex) str -> createFromNothing rg str (fun () -> TTRetrieve))); 
      ( new Regex("^nnn"), 
        (fun (rg:Regex) str -> createFromNothing rg str (fun () -> FExit))); 
     ] 
 
 
////////上のComKindLstの要素の型の別名///////////////////////// 
 
type CKL = System.Text.RegularExpressions.Regex * 
                         (System.Text.RegularExpressions.Regex -> string -> (Command * int) option) 
 
///////下のmakeCLSubの補助関数///////////////////////////////// 
 
let rec tryApply (cmdLst:list<CKL>) (str:string) = 
    match cmdLst with 
    | [] -> None 
    | (rg,f)::tl -> let res = f rg str 
                    if res.IsSome then 
                        res 
                    else 
                        tryApply tl str 
///////下のmakeCArrayの補助関数///////////////////////////////// 
 
let rec makeCASub (cmdLst:list<CKL>) (str:string) (index:int) (res:list<Command>) = 
    if str.Length = 0 then  
        res 
    else 
        let matchRes = tryApply cmdLst str 
        if matchRes = None then 
            failwith (sprintf "%d文字目からの部分でマッチするものが見つかりません" index) 
        else 
            let (com,len) = matchRes.Value 
            makeCASub cmdLst (str.Substring(len)) (index + len) (com::res)  
                   
let makeCArray (cmdLst:list<CKL>) (src:string) = 
    makeCASub cmdLst src 0 [] 
    |> List.rev 
    |> Array.ofList 
 
///////状態を表すタプルの別名//////////////////////////////////// 
 
type WState = int*list<int>*Map<int,int>*list<int> 
 
///////それぞれの命令に対応する関数群//////////////////////////// 
 
let do_SDup ((pc,stcLst,heapMap,rIndexLst):WState) = 
    if List.length stcLst = 0 then failwith(sprintf "index:%d スタックが空でDupできません。" pc) 
    (pc+1,(List.head stcLst)::stcLst,heapMap,rIndexLst) 
 
let do_SSwap((pc,stcLst,heapMap,rIndexLst):WState) = 
    match stcLst with 
    |h1::h2::tl -> (pc+1,h2::h1::tl,heapMap,rIndexLst) 
    | _-> failwith(sprintf "index:%d スタックの要素の個数が1以下です" pc) 
   
let do_SDiscard ((pc,stcLst,heapMap,rIndexLst):WState) = 
    if List.length stcLst = 0 then failwith(sprintf "index:%d スタックが空でDiscardできません。" pc) 
    (pc+1,(List.tail stcLst),heapMap,rIndexLst) 
 
let do_SPush (num:int) ((pc,stcLst,heapMap,rIndexLst):WState) = 
    (pc+1,num::stcLst,heapMap,rIndexLst) 
 
let do_SCopy (n:int) ((pc,stcLst,heapMap,rIndexLst):WState) =     
    if (List.length stcLst) <= n then  failwith(sprintf "index:%d スタックの要素数がたりずにSCopyできません。" pc) 
    let tempArr = Array.ofList stcLst 
    (pc+1,(tempArr.[n])::stcLst,heapMap,rIndexLst) 
     
let do_SSlide (n:int) ((pc,stcLst,heapMap,rIndexLst):WState) = 
    if (List.length stcLst) <= n then  failwith(sprintf "index:%d スタックの要素数がたりずにSSlideできません。" pc) 
    let tempArr = Array.ofList stcLst 
    let slicedArr = tempArr.[(n + 1) ..] 
    let newStcLst = (List.head stcLst)::(List.ofArray slicedArr) 
    (pc+1,newStcLst,heapMap,rIndexLst) 
 
let do_OpSub (op:int->int->int) ((pc,stcLst,heapMap,rIndexLst):WState) = 
    match stcLst with 
    |v1::v2::rem -> (pc+1,(op v2 v1)::rem,heapMap,rIndexLst) 
    | _     ->failwith(sprintf "index:%d スタックの要素数がたりずに演算できません。" pc) 
     
let do_TSAdd (t:WState) =  
    do_OpSub (+) t   
 
let do_TSSub (t:WState) =  
    do_OpSub (-) t   
 
let do_TSMul (t:WState) =  
    do_OpSub (*) t   
 
let do_TSDiv (t:WState) =  
    do_OpSub (/) t   
 
let do_TSMod (t:WState) =  
    do_OpSub (%) t   
 
let do_TTStore ((pc,stcLst,heapMap,rIndexLst):WState) = 
    match stcLst with 
    |v1::v2::rem -> (pc+1,rem,Map.add v2 v1 heapMap,rIndexLst) 
    |_    ->failwith(sprintf "index:%d スタックの要素数がたりずにStoreできません。" pc) 
 
let do_TTRetrieve ((pc,stcLst,heapMap,rIndexLst):WState) = 
    match stcLst with 
    |v::rem -> let retreivedVal = Map.tryFind v heapMap 
               if retreivedVal.IsSome then 
                    (pc+1,retreivedVal.Value::rem,heapMap,rIndexLst) 
               else failwith(sprintf "index:%d 指定されたアドレスにデータがないためRetrieveできません。" pc) 
    |_    ->failwith(sprintf "index:%d スタックの要素数がたりずにRetrieveできません。" pc) 
 
let do_FExit ((pc,stcLst,heapMap,rIndexLst):WState) =     
    () 
 
////////命令を解釈しながら状態を変化させていく中心の関数//////////////// 
 
let rec processCmd (cmds :Command[]) ((pc,stcLst,heapMap,rIndexLst) as t:WState) = 
    if pc < 0 || pc >= Array.length cmds then failwith (sprintf "index:%d pcが領域外です" pc) 
    printfn "%A" t  //デバック用 
    let cur_cmd = cmds.[pc] 
    printfn "%A" cur_cmd //デバック用 
    match cur_cmd with 
    |SPush(num)  -> do_SPush num t  |> (processCmd cmds) 
    |SDup        -> do_SDup t       |> (processCmd cmds) 
    |SCopy (n)   -> do_SCopy n t    |> (processCmd cmds) 
    |SSwap       -> do_SSwap t      |> (processCmd cmds) 
    |SDiscard    -> do_SDiscard t   |> (processCmd cmds) 
    |SSlide (n)  -> do_SSlide n t   |> (processCmd cmds) 
    |TSAdd       -> do_TSAdd t      |> (processCmd cmds) 
    |TSSub       -> do_TSSub t      |> (processCmd cmds) 
    |TSMul       -> do_TSMul t      |> (processCmd cmds) 
    |TSDiv       -> do_TSDiv t      |> (processCmd cmds) 
    |TSMod       -> do_TSMod t      |> (processCmd cmds) 
    |TTStore     -> do_TTStore t    |> (processCmd cmds) 
    |TTRetrieve  -> do_TTRetrieve t |> (processCmd cmds) 
    |FExit       -> do_FExit t
スポンサーサイト

テーマ : プログラミング
ジャンル : コンピュータ

コメントの投稿

非公開コメント

プロフィール

T GYOUTEN

Author:T GYOUTEN
F#と英単語とフリーソフトと読書に興味があります。
ホームページでフリーソフトも公開しています。どぞ御贔屓に。

最新記事
最新コメント
最新トラックバック
月別アーカイブ
カテゴリ
フリーエリア
フリーエリア
blogram投票ボタン
検索フォーム
RSSリンクの表示
リンク
ブロとも申請フォーム

この人とブロともになる

QRコード
QRコード
上記広告は1ヶ月以上更新のないブログに表示されています。新しい記事を書くことで広告を消せます。