スポンサーサイト

上記の広告は1ヶ月以上更新のないブログに表示されています。
新しい記事を書く事で広告が消せます。

F#で入門 コンパイラ 、インタプリタ編 LR1TokenizeAndParseクラス化を利用したWinソフト(2)

 今回は前回作成したソフトに少し改良を加えてみます。 
前回のソフトで使いにくい部分は、テキストボックスへの入力部分です。 
RPAR,\( 
LPAR,\) 
ADD,\+ 
SUB,\- 
MUL,\* 
DIV,\/ 
NUM,0|[1-9][0-9]* 
とか入力するのですが、visual studioのF#のソースにする場合は 
let t =   
    [ 
    "RPAR","\("; 
    "LPAR","\)"; 
    "ADD","\+"; 
    "SUB","\-"; 
    "MUL","\*"; 
    "DIV","\/"; 
    "NUM","0|[1-9][0-9]*"; 
    ] 
という形になります。 
ということで、ソフト上でこの二つの形を相互変換できるようにしたいと思います。 
(文法ルールも同様に相互変換できるようにします。) 
 
ソフト側で入力しておいて 
 
1033-1.jpg 
 
「->」ボタンを押すと 
 
1033-2.jpg 
 
逆にvisual studioのソース部分を右側にコピペしておいて 
(なお、各ルール毎に改行しておくことが必要です。) 
 
 
1033-3.jpg
 
「<-」ボタンを押すと 
 
1033-4.jpg
 
となるようにします。 
 
全体は下の通りです。 
 
1033-5.jpg
 
全コードは次の通りです。 
 open System    
open System.Windows.Forms    
open System.Drawing    
open System.Text.RegularExpressions   
 
//文法定義のエラー 
exception MyGramExcp of string 
 
let STR_EPS ="EPSILON" 
 
//引数分の空白文字を作る補助関数 
let spaceStr(i) =  
    let sb = new System.Text.StringBuilder() 
    let rec addSpace count = 
        if count = i then sb.ToString() 
        else 
            sb.Append(" ") |> ignore 
            addSpace (count + 1) 
    addSpace 0  
 
 
////////////////////////////////////////////////////////////////////////////////////////////////////////////////// 
 
type Token(kind:string,img:string,row:int,col:int) = 
    member this.Kind = kind 
    member this.Img = img 
    member this.Row = row 
    member this.Col = col 
 
    override this.ToString() = 
        sprintf "[%s %s (%d,%d)] " kind img row col 
 
//一行をトークン化したときの結果用の型 
type TokenizeOneLineResult = 
    |TOLSuccess of list<Token> 
    |TOLFail of int*int //トークン化失敗したときの行と列 
 
    member this.IsSuccess () = 
        match this with 
        |TOLSuccess(_) -> true 
        | _ -> false 
 
type LR0ItemType = int * int * string * string * string * string list 
//                (1,3, "Program", "RPAR", "NULL", ["LPAR"; "Seq"; "RPAR"; "@"]) 
//タプルの第二成分は同一構文規則内の通し番号、一つ大きいのがマーカーを一つ後ろにずらしたもの 
 
type LR1ItemType = LR0ItemType*Set<string> //Set<string>は先読み記号 
//例 ((3, 1, "Exp", "NULL", "Exp", ["@"; "Exp"; "ADD"; "Term"]),["EOF"]) 
 
//StateとしてはLR0と同じものを使用 
type LR0State = 
    SHIFT of int  //構文番号(オートマトンの番号) 
    |REDUCE of int*int*string //構文番号(オートマトンの番号ではない)* 還元項の右辺の要素数(@は含まない)* 構文の左辺の非終端名 
    |ACCEPT 
 
              //文法番号スタック*入力トークン種別の残り 
type anaState = list<int>*list<string> 
 
 
//具象構文木 
type embodyST = 
    |EPS_Leaf of Token //tokenは存在しないので、εの直後のtokenを与える 
    |Leaf of Token  
    |Node of (int* string * list<embodyST>) //intは構文規則番号,stringは "(1, "Program", ["DeclStmts"; "PrintStmts"])"等 
 
    //表示用 
    member this.dispStr (inc :int)  = //inc = インシデント 
            match this with 
            |EPS_Leaf (token) 
                -> spaceStr(inc) +  "ε" + (sprintf "(%d,%d)の前" token.Row token.Col ) + "\r\n" 
            |Leaf(token) 
                -> spaceStr(inc) +  token.ToString() + "\r\n"  
            |Node(index,str,lst)  
                -> spaceStr(inc) + (sprintf "(%d)" index) + str + "\r\n"  
                   + List.fold (fun state (ele:embodyST) -> state + (ele.dispStr (inc + 4)) ) "" lst  
 
///////////////////////////////// 
 
type LR1TokenizeAndParse (inDefLst:list<string*string>, inStrLst:list<string>) = 
 
    let initStrLst = "0:Z = Program EOF" :: inStrLst 
    let initDefLst =  ("EOF","EOF"):: inDefLst 
 
    let makeTokenizeRules (inDefLst:list<string*string>) = 
        inDefLst 
            |> List.map(fun (name,rgText) ->(name,(new Regex ( @"^(?<sPart>\s*)(?<parts>" + rgText + @")")))) 
 
    let tokenizeTopPart (textPart:string) (trl:list<string*Regex>) (row:int) (col:int) = 
        trl 
          |>List.fold (fun (curToken:Token,curLongestLength:int) (name,rg) -> 
                            let wholeMatch = rg.Match(textPart) 
                            let partMatch = wholeMatch.Groups.["parts"]  //必要な部分 
                            let sPartMatch = wholeMatch.Groups.["sPart"] //先頭の空白部分 
                            if wholeMatch.Value.Length > curLongestLength then //最長マッチ 
                                (new Token(name,partMatch.Value,row, col + sPartMatch.Value.Length),wholeMatch.Value.Length ) 
                            else 
                                (curToken,curLongestLength) 
                      ) 
                      (new Token("","",0,0),0) 
 
 
    let tokenizeOneLine (inDefLst:list<string*string>) (inRow:int) (inOneLineStr:string) = 
        let trs = makeTokenizeRules inDefLst 
        let rec tokenizeOneLineSub (curCol:int) (remainStr:string) res = 
            if remainStr.Trim().Length = 0 then 
                TOLSuccess(List.rev res) 
            else 
               let (slicedToken,length) = tokenizeTopPart remainStr trs inRow curCol 
               if length = 0 then 
                    let topBlankNum = remainStr.Length - remainStr.TrimStart().Length 
                    TOLFail(inRow,curCol+topBlankNum) 
               else 
                  tokenizeOneLineSub (curCol + length) (remainStr.Substring(length)) (slicedToken::res)        
        tokenizeOneLineSub 1 inOneLineStr [] 
 
    let tokenizer  (source:list<string>) = 
        let oneLineTokenizer = tokenizeOneLine initDefLst 
        let isTOLSuccess (x:TokenizeOneLineResult) = 
            match x with 
            |TOLSuccess(_) -> true 
            |_             -> false 
        let sucLst,failLst = 
            source 
            |>List.map (fun str -> str.TrimEnd()) 
            |>List.mapi (fun i str -> oneLineTokenizer (i+1) str ) 
            |>List.partition (fun tr -> tr.IsSuccess () ) 
        if failLst.Length > 0 then  
            failwith (sprintf "%A" failLst) 
        else  
            sucLst 
              |>List.map (fun tolr -> match tolr with 
                                         |TOLSuccess(tol) -> tol 
                                         | _ -> failwith "error" //これは起こらない 
                         ) 
              |>List.fold (fun s lst -> s @ lst) [] 
         
    let splitOneLineGram (inStr:string)= 
        let (lhdIndex,rhd) =  
            match inStr.Split([|':'|]) with 
            [|mlhd;mrhd|]  ->  (mlhd.Trim(),mrhd) 
            | _             ->  raise <| MyGramExcp(inStr)  
        let (lhd,rhd2) = 
            match rhd.Split([|'='|]) with 
            |[|mlhd;mrhd|]  ->  (mlhd.Trim(),mrhd) 
            | _             ->  raise <| MyGramExcp(inStr)  
        let rhdElems =  
            rhd2.Split([|' '|]) 
                |> List.ofArray 
                |> List.map (fun s -> s.Trim()) 
                |> List.filter (fun s -> s <> "") 
        (System.Int32.Parse(lhdIndex),lhd,rhdElems) 
 
 
    let getNTN_TN__Sets (inStrLst:list<string>) = 
        let (sumUpLhdSet,sumUpRhdSet) = 
            inStrLst 
                |> List.map splitOneLineGram 
                |> List.fold (fun (acclh,accrh)  (_,lhd,rhdLst) -> (lhd :: acclh,rhdLst @ accrh)) ([],[]) 
                |> (fun (hdLst,rhLst) -> (Set.ofList hdLst, Set.ofList rhLst)) 
        (sumUpLhdSet,sumUpRhdSet - sumUpLhdSet - (Set.ofList [STR_EPS])) 
 
    let (ntnSet,tnSet) =  getNTN_TN__Sets initStrLst   
 
 
    let isNullableToken ((in_ntn,in_tn):Set<string>*Set<string>) (in_ntnNullableMap:Map<string,bool>)(inTokenName:string) = 
        if inTokenName = STR_EPS then  
             true 
        elif Set.contains inTokenName in_tn then 
             false 
        else 
            in_ntnNullableMap.[inTokenName] 
 
    let isNullableTokenLst ((in_ntn,in_tn):Set<string>*Set<string>) (in_ntnNullableMap:Map<string,bool>)(inTokenNameLst:list<string>) = 
          List.forall (isNullableToken (in_ntn,in_tn) in_ntnNullableMap )inTokenNameLst //リスト中のすべてのtokenがnullableか 
           
    let isNullableTokenLstLst ((in_ntn,in_tn):Set<string>*Set<string>) (in_ntnNullableMap:Map<string,bool>)(inTokenNameLstLst:list<list<string>>) = 
          List.exists (isNullableTokenLst (in_ntn,in_tn) in_ntnNullableMap ) inTokenNameLstLst//リスト中のどれかのtokenリストがnullableか 
 
    let grams = initStrLst 
                    |> List.map splitOneLineGram 
                    |> List.map (fun (_,lh,rhEles) -> (lh,rhEles)) //[("Program",["DeclStmts";"PrintStmts"]);("DeclStmts",["VAR";"SEMI"])] 
  
    let getNTN_NullableMap (inStrLst:list<string>) = 
     
    
        let rec getNTN_NullableMapSub (inOldNullableMap:Map<string,bool>) (count:int) =  
            let nextNullableMap = 
                ntnSet 
                    |> Set.fold (fun stateMap ele -> 
                                    let targetGramsLstLst = 
                                        grams 
                                            |>List.filter (fun (ntnName,_) -> ntnName = ele) 
                                            |>List.map (fun (_,lst) -> lst) 
                                    let thisEleNullable = 
                                        isNullableTokenLstLst(ntnSet,tnSet) inOldNullableMap targetGramsLstLst 
                                    Map.add ele thisEleNullable stateMap 
                                 ) 
                                 Map.empty 
            if count > 10000 then 
                failwith "count error" 
            elif nextNullableMap = inOldNullableMap then 
                nextNullableMap 
            else 
                getNTN_NullableMapSub nextNullableMap (count + 1) 
     
        let initNullableMap = 
                    ntnSet 
                        |> Set.map (fun ele -> (ele,false)) 
                        |> Map.ofSeq 
     
        getNTN_NullableMapSub initNullableMap 0 
 
 
    let ntnNullableMap = getNTN_NullableMap initStrLst 
 
 
    let getFirstSetOfToken ((in_ntn,in_tn):Set<string>*Set<string>) (in_ntnFirstSetMap:Map<string,Set<string>>)(inTokenName:string) = 
        if inTokenName = STR_EPS then  
             Set.empty 
        elif Set.contains inTokenName in_tn then 
             Set.ofList ([inTokenName]) 
        else 
            in_ntnFirstSetMap.[inTokenName] 
 
    let getFirstSetOfTokenLst ((in_ntn,in_tn):Set<string>*Set<string>) (in_ntnNullableMap:Map<string,bool>) 
                               (in_firstSetMap:Map<string,Set<string>>) (inTokenNameLst:list<string>) = 
          let isNullableTokenPartApply = isNullableToken (in_ntn,in_tn) in_ntnNullableMap    
       
          let rec getFirstSetOfTokenLstSub (tokenLst:list<string>)  = 
            match tokenLst with 
            |[] -> Set.empty 
            |hd::tl when isNullableTokenPartApply hd -> (getFirstSetOfToken (in_ntn,in_tn) in_firstSetMap hd) + (getFirstSetOfTokenLstSub tl) 
            |hd::tl                                  -> (getFirstSetOfToken (in_ntn,in_tn) in_firstSetMap hd) 
 
          getFirstSetOfTokenLstSub inTokenNameLst 
 
    let getFirstSetOfTokenLstLst ((in_ntn,in_tn):Set<string>*Set<string>) (in_ntnNullableMap:Map<string,bool>) 
                              (in_firstSetMap:Map<string,Set<string>>) (inTokenNameLstLst:list<list<string>>) =   
 
        let getFirstSetOfTokenLstPartApply = getFirstSetOfTokenLst (in_ntn,in_tn) in_ntnNullableMap in_firstSetMap 
     
        List.fold (fun acc ele -> acc + (getFirstSetOfTokenLstPartApply ele)) Set.empty inTokenNameLstLst 
 
    let getNTN_FirstMap  (inStrLst:list<string>) = 
     
        let FisrtSetOfTokenLstLstPA = getFirstSetOfTokenLstLst (ntnSet,tnSet) ntnNullableMap 
     
        let rec getNTN_FirstMapSub (inOldFirstMap:Map<string,Set<string>>) (count:int) =  
            let nextFirstMap = 
                ntnSet 
                    |> Set.fold (fun stateMap ele -> 
                                    let targetGramsLstLst = 
                                        grams 
                                            |>List.filter (fun (ntnName,_) -> ntnName = ele) 
                                            |>List.map (fun (_,lst) -> lst) 
                                    let thisEleFisrtSet = 
                                         FisrtSetOfTokenLstLstPA inOldFirstMap targetGramsLstLst 
                                    Map.add ele thisEleFisrtSet stateMap 
                                 ) 
                                 Map.empty 
            if count > 10000 then 
                failwith "count error" 
            elif nextFirstMap = inOldFirstMap then 
                nextFirstMap 
            else 
                getNTN_FirstMapSub nextFirstMap (count + 1) 
     
        let initFirstMap = 
                    ntnSet 
                        |> Set.map (fun ele -> (ele,Set.empty)) 
                        |> Map.ofSeq 
     
        getNTN_FirstMapSub initFirstMap 0 
 
    let ntnFirstMap = getNTN_FirstMap initStrLst 
     
    let getAfterTokens (inStr:string) ((lhdStr,rhStrLst):string*list<string>) = 
        let rec getAfterTokensSub strLst res = 
            match strLst with 
            |hd::tl when hd = inStr -> getAfterTokensSub tl ((tl,lhdStr)::res) 
            |hd::tl                 -> getAfterTokensSub tl res 
            | [] -> res 
        getAfterTokensSub rhStrLst [] 
     
    let getNTN_FollowMap  (inStrLst:list<string>) = 
        let isNullableTokensLstPA (tokenLst:list<string>) = isNullableTokenLst (ntnSet,tnSet) ntnNullableMap tokenLst 
        let getFirstSetOfTokenLstPA (tokenLst:list<string>) = getFirstSetOfTokenLst (ntnSet,tnSet) ntnNullableMap  ntnFirstMap tokenLst 
  
        let rec getNTN_FollowMapSub (inOldFollowMap:Map<string,Set<string>>) (count:int) =  
           let getFollowSet (afterTokens:list<string>,ntnName:string) = 
                    if isNullableTokensLstPA afterTokens then 
                        (getFirstSetOfTokenLstPA afterTokens) + (inOldFollowMap.[ntnName]) 
                    else 
                        (getFirstSetOfTokenLstPA afterTokens)                 
           let nextFollowMap = 
                ntnSet 
                    |> Set.fold (fun stateMap ele -> 
                                    let includeEleGrams = 
                                        grams 
                                          |> List.fold (fun state2 (ntnName2,tokenLst) 
                                                            -> state2 @ (getAfterTokens ele (ntnName2,tokenLst))) 
                                                        [] 
                                                     
                                    let followSet = 
                                        includeEleGrams 
                                          |> List.fold (fun (state3:Set<string>) (afterTokens,ntnName) -> 
                                                        state3 + (getFollowSet (afterTokens,ntnName))) 
                                                        Set.empty 
                                    Map.add ele followSet stateMap 
                                 ) 
                                 Map.empty 
           if count > 10000 then 
                failwith "count error" 
           elif nextFollowMap = inOldFollowMap then 
                nextFollowMap 
           else 
                getNTN_FollowMapSub nextFollowMap (count + 1) 
 
 
        let initFollowMap = 
                    ntnSet 
                        |> Set.map (fun ele -> (ele,Set.empty)) 
                        |> Map.ofSeq 
     
        getNTN_FollowMapSub initFollowMap 0 
     
    let ntnFollowMap = getNTN_FollowMap initStrLst 
 
    ///////////////////////////////////////////LR1部分//////////////////////////////////////////////////////////////////////// 
    //マーカーを付けて、マーカーの前後の記号とそれのタプルを返す 
    let addMarkers (idNum:int, lhName:string, inLst:list<string>) = 
        if inLst = [STR_EPS] then 
            [(idNum,1,lhName,"NULL","NULL",["@"])] 
        else 
            let withSenti ="NULL"::inLst @ ["NULL"] 
            let rec addMarkerSub (lst:list<string>) (acchd:list<string>) accLst (counter) = 
                match lst with 
                |hd::tl when tl <> []  
                    -> addMarkerSub tl (acchd @ [hd]) ((idNum,counter,lhName,hd, List.head tl,((acchd @ [hd] @ ["@"] @ tl)))::accLst) (counter+1) 
                |_ ->  accLst |> List.map (fun (id,cnt,lh,bef,aft,resLst) -> (id,cnt,lh,bef,aft,resLst |> List.rev |> List.tail |> List.rev |> List.tail)) 
     
            List.rev (addMarkerSub withSenti [] [] 1) 
 
    let getGramWithMarker (inStr:string) = 
        splitOneLineGram inStr   
          |> addMarkers 
 
    let getLR1Terms (inStrLst:list<string>) = 
       let (ntnSet,ntSet) = getNTN_TN__Sets  inStrLst 
       let lr0TermsSet = 
            inStrLst 
                |> List.map getGramWithMarker 
                |> List.concat 
                |> Set.ofList 
       let shiftItemsSet = //markerの直後が終端記号 
            Set.filter (fun (_,_,_,_,aft,_) -> Set.contains aft ntSet) lr0TermsSet 
       let reduceItemsSet = //markerが末尾 
            Set.filter (fun (_,_,_,_,aft,_) -> aft = "NULL") lr0TermsSet 
       let topMarker_ItemsSet = //markerが先頭 
           Set.filter (fun (_,_,_,bfr,_,_) -> bfr = "NULL") lr0TermsSet 
    
       let ntnAfterMarkerItemsSet = //markerの直後が非終端記号 
          Set.filter (fun (_,_,_,_,aft,_) -> Set.contains aft ntnSet) lr0TermsSet 
   
    
       let lr0TItemsMap = 
         lr0TermsSet  
            |> Set.map (fun (id,subId,lhName,bfr,aft,lst) -> ((id,subId),(id,subId,lhName,bfr,aft,lst))) 
            |> Map.ofSeq   
 
    
       //markerの直後が非終端記号のものについては、その要素とmarkerの直後の非終端記号の後のリストを組にする 
       //補助関数 
       let rec ntnAMSub lst  = 
            match lst with 
            |hd::tl when hd = "@" -> List.tail tl 
            |hd::tl -> ntnAMSub tl  
            | [] -> failwith "neverOccurableError" 
    
       let rec makeMap inLst accMap = 
            match inLst with 
            |[] -> accMap 
            |(id,subId,_,_,_,lst)::tl ->makeMap tl (Map.add (id,subId) (ntnAMSub lst) accMap) 
 
 
       let idSubId2AfterAfterMarkerMap = makeMap (List.ofSeq ntnAfterMarkerItemsSet) Map.empty 
       
       (lr0TermsSet,shiftItemsSet,reduceItemsSet,topMarker_ItemsSet,ntnAfterMarkerItemsSet,lr0TItemsMap,idSubId2AfterAfterMarkerMap) 
 
 
    let getClosure  ((in_ntn,in_tn):Set<string>*Set<string>) (in_ntnNullableMap:Map<string,bool>) 
                    (in_firstSetMap:Map<string,Set<string>>)  
                    (inIdSubId2AfterAfterMarkerMap:Map<(int * int),string list>) (inNtnAfterMarkerItemsSet:Set<LR0ItemType>)  
                    (inTopMarker_ItemSet:Set<LR0ItemType>) (initI :Set<LR1ItemType>) = 
        let rec getClosureSub oldClosureSet = 
                                      //oldClosureSetの中で非終端記号の前にマーカーがついている形のもの 
            let shouldAddedLR1Items  = Set.filter (fun (ele,_) -> Set.contains ele inNtnAfterMarkerItemsSet) oldClosureSet 
            let newClosureSet = 
                Set.fold  (fun oldClosureSet ((id,subId,_,_,aft0,_),lookAheads) -> //aftはマーカーの直後の非終端記号 
                                let addLRItemBases:Set<LR0ItemType> = Set.filter (fun (_,_,lh,_,_,_ ) -> lh = aft0) inTopMarker_ItemSet 
                                let addLR1Items = 
                                    addLRItemBases 
                                      |> Set.map (fun lr0Item -> 
                                                    let afterAfterMarkerLst = inIdSubId2AfterAfterMarkerMap.[(id,subId)]  
                                                    let afterAfterMarkerNullable = 
                                                        isNullableTokenLst (in_ntn,in_tn) in_ntnNullableMap afterAfterMarkerLst 
                                                    let afterAfterMarkerFirst = 
                                                         getFirstSetOfTokenLst (in_ntn,in_tn) in_ntnNullableMap in_firstSetMap afterAfterMarkerLst 
                                                    let addLR1ItemLookAheads = 
                                                          if afterAfterMarkerNullable = true then  
                                                                afterAfterMarkerFirst + lookAheads 
                                                          else 
                                                                afterAfterMarkerFirst 
                                                    (lr0Item,addLR1ItemLookAheads) 
                                                  ) 
                                oldClosureSet + addLR1Items 
                            ) 
                           oldClosureSet 
                           shouldAddedLR1Items 
            if newClosureSet = oldClosureSet then 
                 newClosureSet 
            else  
                getClosureSub newClosureSet 
 
        let res0Lst = List.sort (List.ofSeq (getClosureSub initI))  
         //ここまででは(5, 1, "Term", "NULL", "ID", ["@"; "ID"]), set ["ADD"]);((5, 1, "Term", "NULL", "ID", ["@"; "ID"]), set ["EQ2"] 
        //とまとめるべきものがバラバラになっているのでこれをまとめる。 
 
        let dummyEle = ((-1,-1,"","","",[]),Set.empty) 
    
        let (res,_) =  //最後のdummyEleが_にくる 
              (res0Lst @ [dummyEle]) |>   
              List.fold (fun (acc:Set<LR1ItemType>,(oldlr0Part:LR0ItemType,oldLookAheadsPart:Set<string>)) (lr0Part:LR0ItemType,lookAhedsPart:Set<string>) 
                                    ->if oldlr0Part = lr0Part then 
                                            (acc, (oldlr0Part,oldLookAheadsPart + lookAhedsPart)) 
                                      else       
                                            ((Set.add (oldlr0Part,oldLookAheadsPart) acc),(lr0Part,lookAhedsPart)) 
                            ) 
                 (Set.empty,dummyEle) 
 
      
        Set.filter (fun ((a,_,_,_,_,_),_) -> a <> -1) res //最初のdummyEleを除く(これがgetClosureの返り値) 
 
 
    let getGoto  ((in_ntn,in_tn):Set<string>*Set<string>) (in_ntnNullableMap:Map<string,bool>) 
                    (in_firstSetMap:Map<string,Set<string>>)  
                    (inIdSubId2AfterAfterMarkerMap:Map<(int * int),string list>) (inNtnAfterMarkerItemsSet:Set<LR0ItemType>)  
                    (inTopMarker_ItemSet:Set<LR0ItemType>)  (inIRItemMap:Map<(int*int),LR0ItemType>) 
                    (inLR1ItemSet:Set<LR1ItemType>) (inStr:string) = 
 
 
        let getClosurePA = getClosure (in_ntn,in_tn) in_ntnNullableMap in_firstSetMap inIdSubId2AfterAfterMarkerMap 
                                        inNtnAfterMarkerItemsSet inTopMarker_ItemSet 
        let shouldAddGredienceLR1Items = Set.filter (fun ((_,_,_,_,aft,_),_) -> aft = inStr) inLR1ItemSet  
        let tempSet = //マーカーをずらしたものの集合 
                shouldAddGredienceLR1Items 
                    |> Set.fold (fun accSet ((i,j,_,_,_,_),lookAheads) ->   
                                    let addItemLR0Part = inIRItemMap.[(i,j+1)] //(マーカーを一つ進めたもの(マーカーの次はinStr))  
                                    let addLR1Item = (addItemLR0Part,lookAheads) 
                                    Set.add addLR1Item accSet   
                                ) 
                       Set.empty  
     
        getClosurePA tempSet 
 
 
    let makeLR1Map (inGrams:list<string>) = 
     
        let (ntnSet,tnSet) = getNTN_TN__Sets  inGrams 
        let wholeNtnAndTnLst = List.ofSeq(ntnSet + tnSet) 
        let (whole,shift,reduce,topM,ntnAftM,lr0TItemsMap,idSubId2AfterAfterMarkerMap) = getLR1Terms inGrams 
     
        let (ntn,tn) = getNTN_TN__Sets inGrams 
        let ntnNullableMap = getNTN_NullableMap inGrams 
        let firstSetMap = getNTN_FirstMap inGrams 
 
        //受理状態のみを含むClosureか  
        let isFinalLR1Item (cls:Set<LR1ItemType>)  =  
               (Set.exists (fun ((_,_,lh,bfr,aft,_),_) ->lh = "Z" && bfr = "Program" && aft = "EOF") cls)  && (Set.count cls = 1) 
 
 
        //引数のmapに受理状態のみを含むClosureについてEOFの欄だけの項を付け加えて返す。(「noは受理状態のみを含むClosure」の番号を渡す) 
        let addFinalRow2map (idNo:int) (seedMap:Map<int*string,LR0State>) = 
               List.fold  (fun stateMap ele -> 
                                if ele <> "EOF" then stateMap  //なにもマップに付け加えない。 
                                else Map.add (idNo,"EOF") ACCEPT stateMap 
                          ) 
                          seedMap 
                          wholeNtnAndTnLst 
 
        let getGotoPA = getGoto (ntn,tn) ntnNullableMap firstSetMap idSubId2AfterAfterMarkerMap ntnAftM topM lr0TItemsMap 
 
 
        let rec makeMapSub (ntn_tnLst:List<string>) (curProcessingClsNo:int) (curExistClsNum:int)  
                           (accCls2IdMap:Map<Set<LR1ItemType>,int>) (accId2ClsMap:Map<int,Set<LR1ItemType>>)  
                           (accMap:Map<int*string,LR0State>) = 
            //表の右下まで到達 
            if ntn_tnLst = [] && curProcessingClsNo = curExistClsNum then  
                    (accId2ClsMap,accMap) 
            //表の右端まで到達 
            elif ntn_tnLst = [] && curProcessingClsNo < curExistClsNum then 
                    makeMapSub wholeNtnAndTnLst (curProcessingClsNo + 1)  curExistClsNum  accCls2IdMap accId2ClsMap accMap 
            //受理状態のみを含むClosureの左端の場合 
            elif  isFinalLR1Item  accId2ClsMap.[curProcessingClsNo] = true then  
                    let addedMap = addFinalRow2map curProcessingClsNo accMap 
                    makeMapSub wholeNtnAndTnLst (curProcessingClsNo + 1) curExistClsNum  accCls2IdMap accId2ClsMap addedMap 
            //一般状態 
            else     
               match ntn_tnLst with 
                |[] -> //右端に来る場合は最初の2つの場合でチェック済み 
                    failwith "neverOccurable Error" 
                |hd::tl -> 
                    //還元の可能性を調べる(ここの扱いがSLRと異なる) 
                    let reduceItems = 
                       accId2ClsMap.[curProcessingClsNo] 
                        |> Set.filter (fun ((_,_,_,_,aft,_),lookAheads) -> aft = "NULL" && Set.contains hd lookAheads ) 
                    if  Set.count reduceItems > 1 then 
                        failwith (sprintf "還元/還元衝突 %s  %A " hd reduceItems ) 
                 
                    elif Set.count reduceItems = 1 then //還元項がある場合 
                        //シフトの可能性を調べる 
                        let shiftableItems =  
                            accId2ClsMap.[curProcessingClsNo]  
                                |>Set.filter (fun ((_,_,_,_,aft,_),_) -> aft = hd)   
                     
                        if Set.count shiftableItems >= 1 then 
                            failwith (sprintf "シフト/還元衝突 %s  reduceItems = %A \n shiftItem = %A" hd reduceItems shiftableItems ) 
                        else //還元としてMapに追加 
                            match List.head (List.ofSeq reduceItems) with //要素は一個だけ 
                            |((gramNo,_,lhName,_,_,lstWithMarker),_) ->  
                                    makeMapSub tl curProcessingClsNo curExistClsNum accCls2IdMap accId2ClsMap  
                                            (Map.add (curProcessingClsNo,hd) (REDUCE(gramNo,((List.length lstWithMarker) - 1),lhName))  accMap)  
                 
                    else //還元しない場合(シフトもしくは対象なしの場合) 
                        let newGoto = getGotoPA accId2ClsMap.[curProcessingClsNo] hd //処理中のclosureとtermからGoto集合を求める 
                        if newGoto = Set.empty then //行先なし(表として空欄になる)場合(なにも付け加えない) 
                               makeMapSub tl curProcessingClsNo curExistClsNum accCls2IdMap accId2ClsMap accMap 
                        else 
                            match (Map.tryFind newGoto accCls2IdMap) with 
                            //newGotoがすでに、Closureとして存在する場合 
                            |Some(i) -> makeMapSub tl curProcessingClsNo curExistClsNum  
                                                   accCls2IdMap accId2ClsMap (Map.add (curProcessingClsNo,hd)  (SHIFT(i)) accMap) 
                            //newGotoがまだ、Closureとして存在しない場合 
                            |None    ->let newAccCls2IdMap = Map.add newGoto (curExistClsNum + 1) accCls2IdMap 
                                       let newAccId2ClsdMap = Map.add (curExistClsNum + 1) newGoto accId2ClsMap 
                                       makeMapSub tl curProcessingClsNo (curExistClsNum + 1)  
                                                   newAccCls2IdMap newAccId2ClsdMap (Map.add (curProcessingClsNo,hd)  (SHIFT(curExistClsNum + 1)) accMap)  
 
 
        let initI = ((0,1, "Z", "NULL", "Program", ["@"; "Program"; "EOF"]),Set.ofList ["EOF"]) 
        let cls1 = getClosure  (ntn,tn) ntnNullableMap firstSetMap idSubId2AfterAfterMarkerMap ntnAftM topM (Set.ofList [initI]) 
        let initAccCls2IdMap = Map.ofList [(cls1,1)] 
        let initId2accCls = Map.ofList [(1,cls1)] 
        makeMapSub wholeNtnAndTnLst 1 1  initAccCls2IdMap initId2accCls Map.empty 
 
 
    //リストからn個の要素をpopして残りを返す補助関数 
    let popN in_lst in_n = 
        let rec popNSub lst count = 
            if count = in_n then 
                lst 
            else 
                popNSub (List.tail lst) (count + 1) 
        popNSub in_lst 0 
 
 
    //リストからn個の要素をpopしてpopしたものと残りを返す補助関数 
    let getPopN in_lst in_n = 
        let rec popNSub lst acc count = 
            if count = in_n then 
                (List.rev acc,lst) 
            else 
                popNSub (List.tail lst) ((List.head lst)::acc) (count + 1) 
        popNSub in_lst [] 0 
 
    /////////////////id2gramRuleMapは構文番号->構文内容へのMap 
    let getTree (id2gramRuleMap:Map<int,string>) (in_idTerm2VLR1Map:Map<int*string,LR0State>) (inTokenLst:list<Token>) = 
         
        let rec getTreeSub  ((stk,rem):anaState) (stkOfTree:list<embodyST>,remOfTree:list<embodyST>)= 
            let curAtmtnst = List.head stk 
            let topRemain = List.head rem 
            let nextMove = Map.tryFind   (curAtmtnst,topRemain) in_idTerm2VLR1Map 
            let topRemainNode = List.head remOfTree 
            match nextMove with 
            |Some(SHIFT(nextAtmtnNo)) -> 
                        getTreeSub (nextAtmtnNo::stk,List.tail rem) (topRemainNode::stkOfTree,List.tail remOfTree) 
             
            |Some(REDUCE(ruleNo,graEleNum,lhName)) -> 
                        let (popNodes,remT) = getPopN stkOfTree graEleNum 
                        getTreeSub (popN stk graEleNum ,lhName::rem) (remT,(Node(ruleNo,id2gramRuleMap.[ruleNo],(List.rev popNodes)))::remOfTree) 
            |Some(ACCEPT)->      //終了の場合は状態を変えない 
                    List.head stkOfTree 
            |None   -> 
                    failwith "ソースが文法にのっとっていません" 
         
        let initTokenKindLst = inTokenLst |> List.map (fun tkn -> tkn.Kind) 
        let initNodeLst = inTokenLst |> List.map (fun tkn -> Leaf(tkn)) 
 
        getTreeSub ([1],initTokenKindLst) ([],initNodeLst) 
 
  
    let id2gramRuleMap = //[(5,"5:Program = DeclStmts PrintStmts");.....という形 
          initStrLst 
            |> List.map (fun s ->  
                            let (no,lhName,_) = splitOneLineGram s 
                            (no,s) 
                        ) 
            |> Map.ofList 
 
    //このMapを使ってトークン列を解析する 
    let (_,lr1Map) = makeLR1Map initStrLst 
    let getTreePA = getTree id2gramRuleMap lr1Map 
 
     
    member this.GetNntnSetAdnTnSet () = 
        (ntnSet,tnSet) 
    
    member this.GetTokens (sourceLst:list<string>) =   
        tokenizer sourceLst   
 
 
    member this.GetEBASTtree (sourceLst:list<string>) =   
        let forTokenizedLst =  sourceLst @ ["EOF"] 
        let tokens = tokenizer forTokenizedLst 
        getTreePA tokens 
 
///////////////type LR1TokenizeAndParse end/////////////////////////////////////////////////////////////////////////// 
 
 
let f2c x = x :> System.Windows.Forms.Control  
let conv_btn= new Button(Location = new Point(513, 567),Name = "conv_btn",Size = new Size(41, 63),TabIndex = 75,Text = "→",UseVisualStyleBackColor = true) 
let ast_tb= new TextBox(Location = new Point(560, 444),Multiline = true,Name = "ast_tb",ScrollBars = ScrollBars.Both,Size = new Size(563, 334),TabIndex = 74) 
let term_lb= new ListBox(FormattingEnabled = true,ItemHeight = 12,Location = new Point(14, 313),Name = "term_lb",Size = new Size(128, 100),TabIndex = 73) 
let ntn_lb= new ListBox(FormattingEnabled = true,ItemHeight = 12,Location = new Point(158, 313),Name = "ntn_lb",Size = new Size(143, 100),TabIndex = 72) 
let gram_lb= new ListBox(FormattingEnabled = true,ItemHeight = 12,Location = new Point(322, 313),Name = "gram_lb",Size = new Size(801, 100),TabIndex = 71) 
let label9= new Label(AutoSize = true,Location = new Point(325, 290),Name = "label9",Size = new Size(53, 12),TabIndex = 70,Text = "構文規則") 
let ulabel10= new Label(AutoSize = true,Location = new Point(161, 290),Name = "ulabel10",Size = new Size(65, 12),TabIndex = 69,Text = "非終端記号") 
let label11= new Label(AutoSize = true,Location = new Point(17, 290),Name = "label11",Size = new Size(53, 12),TabIndex = 68,Text = "終端記号") 
let apply_btn= new Button(Location = new Point(131, 264),Name = "apply_btn",Size = new Size(364, 23),TabIndex = 67,Text = "適用",UseVisualStyleBackColor = true) 
let save_btn= new Button(Location = new Point(356, 58),Name = "save_btn",Size = new Size(75, 23),TabIndex = 66,Text = "Save",UseVisualStyleBackColor = true) 
let load_btn= new Button(Location = new Point(275, 58),Name = "load_btn",Size = new Size(75, 23),TabIndex = 65,Text = "Load",UseVisualStyleBackColor = true) 
let llabel10= new Label(AutoSize = true,Location = new Point(242, 41),Name = "llabel10",Size = new Size(73, 12),TabIndex = 64,Text = "εはEPSILON") 
let label7= new Label(AutoSize = true,Location = new Point(242, 30),Name = "label7",Size = new Size(176, 12),TabIndex = 63,Text = "文法番号:非終端記号 = トークン列") 
let label8= new Label(AutoSize = true,Location = new Point(242, 18),Name = "label8",Size = new Size(101, 12),TabIndex = 62,Text = "構文規則(入力用)") 
let base_gram_tb= new TextBox(Location = new Point(230, 114),Multiline = true,Name = "base_gram_tb",ScrollBars = ScrollBars.Both,Size = new Size(294, 141),TabIndex = 61) 
let label6= new Label(AutoSize = true,Location = new Point(18, 419),Name = "label6",Size = new Size(32, 12),TabIndex = 60,Text = "エラー") 
let error_tb= new TextBox(Location = new Point(17, 444),Multiline = true,Name = "error_tb",ScrollBars = ScrollBars.Both,Size = new Size(490, 44),TabIndex = 59) 
let label5= new Label(AutoSize = true,Location = new Point(16, 503),Name = "label5",Size = new Size(33, 12),TabIndex = 58,Text = "ソース") 
let sourceSave_btn= new Button(Location = new Point(406, 494),Name = "sourceSave_btn",Size = new Size(101, 23),TabIndex = 57,Text = "ソースのSave",UseVisualStyleBackColor = true) 
let sourceLoad_btn= new Button(Location = new Point(299, 494),Name = "sourceLoad_btn",Size = new Size(101, 23),TabIndex = 56,Text = "ソースのLoad",UseVisualStyleBackColor = true) 
let source_tb= new TextBox(Location = new Point(12, 523),Multiline = true,Name = "source_tb",ScrollBars = ScrollBars.Both,Size = new Size(495, 255),TabIndex = 55) 
let label4= new Label(AutoSize = true,Location = new Point(16, 52),Name = "label4",Size = new Size(79, 12),TabIndex = 54,Text = "というように記述") 
let label3= new Label(AutoSize = true,Location = new Point(16, 40),Name = "label3",Size = new Size(34, 12),TabIndex = 53,Text = "EQ,\\=") 
let label2= new Label(AutoSize = true,Location = new Point(15, 28),Name = "label2",Size = new Size(68, 12),TabIndex = 52,Text = "INTNUM,\\d+") 
let label1= new Label(AutoSize = true,Location = new Point(15, 10),Name = "label1",Size = new Size(82, 12),TabIndex = 51,Text = "トークン化ルール") 
let tokenRuleSave_btn= new Button(Location = new Point(101, 41),Name = "tokenRuleSave_btn",Size = new Size(132, 23),TabIndex = 50,Text = "トークン化ルールのSave",UseVisualStyleBackColor = true) 
let tokenRuleLoad_btn= new Button(Location = new Point(100, 10),Name = "tokenRuleLoad_btn",Size = new Size(133, 23),TabIndex = 49,Text = "トークン化ルールのLoad",UseVisualStyleBackColor = true) 
let tokenRule_tb= new TextBox(Location = new Point(12, 114),Multiline = true,Name = "tokenRule_tb",ScrollBars = ScrollBars.Both,Size = new Size(203, 141),TabIndex = 48) 
let textBoxPara1= new TextBox(Location = new Point(14, 89),Name = "textBoxPara1",Size = new Size(201, 19),TabIndex = 76) 
let textBoxPara2= new TextBox(Location = new Point(230, 89),Name = "textBoxPara2",Size = new Size(201, 19),TabIndex = 77) 
let buttonConv1= new Button(Location = new Point(536, 118),Name = "buttonConv1",Size = new Size(41, 50),TabIndex = 78,Text = "→",UseVisualStyleBackColor = true) 
let buttonConv2= new Button(Location = new Point(536, 193),Name = "buttonConv2",Size = new Size(41, 50),TabIndex = 79,Text = "←",UseVisualStyleBackColor = true) 
let base_gram_tb2= new TextBox(Location = new Point(805, 118),Multiline = true,Name = "base_gram_tb2",ScrollBars = ScrollBars.Both,Size = new Size(294, 141),TabIndex = 81) 
let tokenRule_tb2= new TextBox(Location = new Point(587, 118),Multiline = true,Name = "tokenRule_tb2",ScrollBars = ScrollBars.Both,Size = new Size(203, 141),TabIndex = 80) 
let button2Clip1= new Button(Location = new Point(589, 87),Name = "button2Clip1",Size = new Size(75, 23),TabIndex = 82,Text = "Clip",UseVisualStyleBackColor = true) 
let button2Clip2= new Button(Location = new Point(805, 85),Name = "button2Clip2",Size = new Size(75, 23),TabIndex = 83,Text = "Clip",UseVisualStyleBackColor = true) 
let Form1= new Form(AutoScaleDimensions = new SizeF(6.0f, 12.0f),AutoScaleMode = AutoScaleMode.Font,ClientSize = new Size(1173, 804),Name = "Form1",Text = "FCCLR1Uti") 
[ f2c button2Clip2; f2c button2Clip1; f2c base_gram_tb2; f2c tokenRule_tb2; f2c buttonConv2; f2c buttonConv1; f2c textBoxPara2; f2c textBoxPara1; f2c conv_btn; f2c ast_tb; f2c term_lb; f2c ntn_lb; f2c gram_lb; f2c label9; f2c ulabel10; f2c label11; f2c apply_btn; f2c save_btn; f2c load_btn; f2c llabel10; f2c label7; f2c label8; f2c base_gram_tb; f2c label6; f2c error_tb; f2c label5; f2c sourceSave_btn; f2c sourceLoad_btn; f2c source_tb; f2c label4; f2c label3; f2c label2; f2c label1; f2c tokenRuleSave_btn; f2c tokenRuleLoad_btn; f2c tokenRule_tb] |> List.iter(fun cnt -> Form1.Controls.Add cnt) 
 
//splitNameDef [|"INTNUM,\d+";"EQ,="|];; 
//結果 (string * string) [] = [|("INTNUM", "\d+"); ("EQ", "=")|] 
let splitNameDef (lst:array<string>) = 
    lst 
      |>Array.filter(fun str -> str.Trim() <> "") 
      |>Array.map(fun (str:string) ->  
                     let posOfKamma = str.IndexOf(',') 
                     let name = str.Substring(0,posOfKamma) 
                     let def = str.Substring(posOfKamma + 1 ,str.Length - posOfKamma - 1) 
                     (name.Trim(),def.Trim()) 
              
                 ) 
 
//仮の初期設定トークン化ルール 
let tnR1 = 
   [("RPAR","\("); 
    ("LPAR","\)"); 
    ("ADD","\+"); 
    ("SUB","\-"); 
    ("MUL","\*"); 
    ("DIV","\/"); 
    ("NUM","0|[1-9][0-9]*") 
    ] 
 
//仮の初期設定文法 
let grammersStrLst1 = 
   ["1:Program = Exp";  
    "2:Exp =  Term"; 
    "3:Exp = Term ADD Term"; 
    "4:Exp = Term SUB Term"; 
    "5:Term = Fact"; 
    "6:Term = Fact MUL Fact"; 
    "7:Term = Fact DIV Fact"; 
    "8:Fact = NUM"; 
    "9:Fact = RPAR Exp LPAR"] 
 
let mutable GL_LR1TAP = new LR1TokenizeAndParse (tnR1,grammersStrLst1) //仮登録  
 
let clearGramPart () = 
    error_tb.Clear() 
    term_lb.Items.Clear() 
    ntn_lb.Items.Clear() 
    gram_lb.Items.Clear() 
 
 
apply_btn.Click.Add 
    (fun _ ->   clearGramPart () 
                try 
                    clearGramPart() 
                    //setTokenizer () 
 
                    let tokenRules = 
                        tokenRule_tb.Text.Replace("\r\n", "\n").Split([|'\n'|]) 
                            |>splitNameDef 
                            |>Array.toList 
  
                    let gramLst =  base_gram_tb.Text.Split([|'\n'|]) 
                                     |> Array.map (fun str -> str.Trim()) 
                                     |> Array.filter(fun str -> str <> "") 
                                     |> List.ofArray  
               
                    GL_LR1TAP <- new LR1TokenizeAndParse ( tokenRules,gramLst) 
                     
                     
                    //非終端記号、終端記号の表示 
                    let (ntnSet,tnSet) = GL_LR1TAP.GetNntnSetAdnTnSet () 
                    Set.iter (fun ele -> ntn_lb.Items.Add(ele) |> ignore ) ntnSet 
                    Set.iter (fun ele -> term_lb.Items.Add(ele) |> ignore ) tnSet 
                    //構文規則の表示 
                    List.iter(fun str -> gram_lb.Items.Add(str) |> ignore ) gramLst 
 
                with 
                |MyGramExcp(str) -> error_tb.Text <- sprintf "構文規則の表記が不正です:%s" str   
                | ex -> error_tb.Text <- ex.Message  
    ) 
 
buttonConv1.Click.Add 
    (fun _ -> try 
                let blank = "    " 
                //トークンルール部分 
                let tokenRules = 
                    tokenRule_tb.Text.Replace("\r\n", "\n").Split([|'\n'|]) 
                        |>splitNameDef 
                        |>Array.toList 
                        |>List.map (fun (str1,str2) -> ("\""+ str1 + "\"" + "," + "\""+ str2 + "\"")) 
                let sb = new System.Text.StringBuilder() 
                sb.Append(sprintf "let %s =  \r\n" textBoxPara1.Text) |> ignore 
                sb.Append(blank + "[\r\n") |> ignore 
                tokenRules |> List.iter (fun str -> sb.Append(blank +  str + ";" + "\r\n") |> ignore) 
                sb.Append(blank + "]" ) |> ignore 
                tokenRule_tb2.Text <- sb.ToString() 
                //文法部分 
                let gramLst =  base_gram_tb.Text.Replace("\r\n", "\n").Split([|'\n'|]) 
                                    |> Array.map (fun str -> str.Trim()) 
                                    |> Array.filter(fun str -> str <> "") 
                                    |> List.ofArray  
 
                let sb_gra = new System.Text.StringBuilder() 
                sb_gra.Append(sprintf "let %s =  \r\n" textBoxPara2.Text) |> ignore 
                sb_gra.Append(blank + "[\r\n") |> ignore 
                gramLst |> List.iter (fun str -> sb_gra.Append(blank +  "\"" + str  + "\"" + ";" + "\r\n") |> ignore) 
                sb_gra.Append(blank + "]" ) |> ignore 
                base_gram_tb2.Text <- sb_gra.ToString() 
 
              with 
              | ex -> error_tb.Text <- ex.Message  
    ) 
 
//下のarrangeTextで使う補助関数、文字列の先頭が(で、最後が)なら、これを取り除く 
let removeLRpar (inStr:string) = 
    let inStrLen = inStr.Length 
    if inStrLen <= 2 then inStr 
    else 
        if inStr.[0] = '(' && inStr.[inStrLen - 1] = ')' then 
            inStr.Substring(1,inStrLen - 2) 
        else 
            inStr 
 
//下のarrangeTextで使う補助関数、最後が;なら、これを取り除く 
let removeEndSemi (inStr:string) = 
    let inStrLen = inStr.Length 
    if inStrLen <= 1 then inStr 
    else 
        if inStr.[inStrLen - 1] = ';' then 
            inStr.Substring(0,inStrLen - 1) 
        else 
            inStr 
 
//下のbuttonConv2.Click.Addで使う補助関数1 
let arangeText (inStr:string) = //各行の最初の空白及び各行の前後の"を取り去る 
    let linesLst = inStr.Trim().Replace("\r\n", "\n").Split([|'\n'|]) 
                    |> Array.map (fun str -> str.Trim()) 
                    |> Array.map (fun str -> str.Replace("\"","")) 
                    |> Array.map (fun str -> removeEndSemi str) 
                    |> Array.map (fun str -> removeLRpar str) 
                    |> List.ofArray 
    let sb = new System.Text.StringBuilder() 
    linesLst |> List.iter (fun str -> sb.Append(str + "\r\n") |> ignore) 
    sb.ToString() 
 
 
buttonConv2.Click.Add 
    (fun _ -> try 
                let rgx = new Regex (@"^\s*let\s*(?<varName>(\w*))\s*=\s*\[(?<contents>(.*|\n|\r\n)*)\]")   
                let tknMatch =rgx.Match(tokenRule_tb2.Text)  
                let tknMatchCont = tknMatch.Groups.["contents"] 
                let tknMatchVarName = tknMatch.Groups.["varName"] 
                tokenRule_tb.Text <- arangeText(tknMatchCont.Value) 
                textBoxPara1.Text <- tknMatchVarName.Value 
 
                let graMatch = rgx.Match(base_gram_tb2.Text) 
                let graMatchCont = graMatch.Groups.["contents"] 
                let graMatchVarName = graMatch.Groups.["varName"] 
                base_gram_tb.Text <- arangeText(graMatchCont.Value) 
                textBoxPara2.Text <- graMatchVarName.Value 
              with 
              | ex -> error_tb.Text <- ex.Message  
    ) 
 
 
conv_btn.Click.Add 
    (fun _ -> try 
                error_tb.Text <- "" 
                ast_tb.Text <- "" 
                let (ntnSet,tnSet) = GL_LR1TAP.GetNntnSetAdnTnSet () 
                let sourceTextArr = source_tb.Text.Replace("\r\n", "\n").Split([|'\n'|]) 
                let sourceLst  = List.ofArray sourceTextArr 
                ast_tb.Text <- GL_LR1TAP.GetEBASTtree(sourceLst).dispStr 4  
 
              with 
              |MyGramExcp(str) -> error_tb.Text <- sprintf "ソースが構文にのっとっていません:%s" str   
              | ex -> error_tb.Text <- ex.Message  
    ) 
 
 
tokenRuleLoad_btn.Click.Add 
    (fun _ -> error_tb.Text <- "" 
              try  
                let ofd = new OpenFileDialog(Filter = "TRファイル(*.tr)|*.tr|すべてのファイル(*.*)|*.*")  
                if(ofd.ShowDialog() = DialogResult.OK) then  
                    let loadedText = 
                        System.IO.File.ReadAllLines (ofd.FileName) 
                            |>splitNameDef         
                            |>Array.fold (fun acc (name,def) -> acc + name + "," + def + "\r\n") "" 
                    tokenRule_tb.Text <- loadedText 
                     
              with  
                | ex -> error_tb.Text <- ex.Message  
    )  
      
      
tokenRuleSave_btn.Click.Add 
    (fun _ -> error_tb.Text <- "" 
              try 
                 
                let sfd = new SaveFileDialog(Filter = "TRファイル(*.tr)|*.tr|すべてのファイル(*.*)|*.*",  
                                              RestoreDirectory = true)  
                if (sfd.ShowDialog() = DialogResult.OK) then  
                    System.IO.File.WriteAllLines(sfd.FileName,(tokenRule_tb.Text.Replace("\r\n", "\n").Split([|'\n'|]))) 
              with  
                | ex -> error_tb.Text <- ex.Message  
    ) 
 
 
sourceLoad_btn.Click.Add 
    (fun _ -> error_tb.Text <- ""  
              try  
                let ofd = new OpenFileDialog(Filter = "srcファイル(*.src)|*.src|すべてのファイル(*.*)|*.*")  
                if(ofd.ShowDialog() = DialogResult.OK) then  
                    use sr = new System.IO.StreamReader(ofd.FileName)  
                    source_tb.Text <- sr.ReadToEnd()  
              with  
                | ex -> error_tb.Text <- ex.Message  
    )  
 
sourceSave_btn.Click.Add  
    (fun _ -> error_tb.Text <- ""   
              try  
                let sfd = new SaveFileDialog(Filter = "srcファイル(*.src)|*.src|すべてのファイル(*.*)|*.*",  
                                              RestoreDirectory = true)  
                if (sfd.ShowDialog() = DialogResult.OK) then  
                    use sw = new System.IO.StreamWriter(sfd.FileName)  
                    sw.Write(source_tb.Text)  
              with  
                | ex -> error_tb.Text <- ex.Message  
                  
    )  
 
  
load_btn.Click.Add  
    (fun _ -> try  
                let ofd = new OpenFileDialog(Filter = "GRA3ファイル(*.gra3)|*.gra3|すべてのファイル(*.*)|*.*")  
                if(ofd.ShowDialog() = DialogResult.OK) then  
                    use sr = new System.IO.StreamReader(ofd.FileName)  
                    base_gram_tb.Text <- sr.ReadToEnd()  
              with  
                | ex -> error_tb.Text <- ex.Message  
    )  
 
  
save_btn.Click.Add  
    (fun _ -> try  
                let sfd = new SaveFileDialog(Filter = "GRA3ファイル(*.gra3)|*.gra3|すべてのファイル(*.*)|*.*",  
                                              RestoreDirectory = true)  
                if (sfd.ShowDialog() = DialogResult.OK) then  
                    use sw = new System.IO.StreamWriter(sfd.FileName)  
                    sw.Write(base_gram_tb.Text)  
              with  
                | ex -> error_tb.Text <- ex.Message  
                  
    )  
 
 
button2Clip1.Click.Add 
    (fun _ -> try 
               tokenRule_tb2.Focus() |> ignore 
               Clipboard.SetText(tokenRule_tb2.Text) 
              with 
                | ex -> error_tb.Text <- ex.Message  
    ) 
 
 
button2Clip2.Click.Add 
    (fun _ -> try 
               base_gram_tb2.Focus() |> ignore 
               Clipboard.SetText(base_gram_tb2.Text) 
              with 
                | ex -> error_tb.Text <- ex.Message  
    ) 
 
[<STAThread()>]   
do Application.Run( Form1) 
 
 
スポンサーサイト

テーマ : プログラミング
ジャンル : コンピュータ

コメントの投稿

非公開コメント

プロフィール

T GYOUTEN

Author:T GYOUTEN
F#と英単語とフリーソフトと読書に興味があります。
ホームページでフリーソフトも公開しています。どぞ御贔屓に。

最新記事
最新コメント
最新トラックバック
月別アーカイブ
カテゴリ
フリーエリア
フリーエリア
blogram投票ボタン
検索フォーム
RSSリンクの表示
リンク
ブロとも申請フォーム

この人とブロともになる

QRコード
QRコード
上記広告は1ヶ月以上更新のないブログに表示されています。新しい記事を書くことで広告を消せます。